#include <LowPower.h>
#include <nRF24L01.h>
#include <printf.h>
#include <RF24.h>
#include <RF24_config.h>
#include <Wire.h>
#include <stdint.h>
#include <SDS011.h>

/* -------CONFIG---------*/
#define LOGDEBUG  0
/* --------------------- */

#define RF24_CH   25
/* --------------------- */


#define SLEEP_DATA   37    //5min , 8s par cycle
#define SLEEP_VOLT   450  //1h
/* --------------------- */


#define VT_PIN    14  //A0
#define SDS_ON    8   //PB0
#define LED_PIN   17  //PC3
/* --------------------- */

//DEBUG 
#if LOGDEBUG==1
#define DEBUG_PRINT(x)       Serial.print(x)
#define DEBUG_PRINTDEC(x)    Serial.print(x, DEC)
#define DEBUG_PRINTLN(x)     Serial.println(x)
#define DEBUG_RADIO()        radio.printDetails()
#else
#define DEBUG_PRINT(x)
#define DEBUG_PRINTDEC(x)
#define DEBUG_PRINTLN(x)
#define DEBUG_RADIO()
#endif
/* --------------------- */

uint16_t  nodeId = NODE_ID;
uint8_t   node_address[5]         = {"1Node"};
uint8_t   server_address[5]       = {"2Node"};
/* --------------------- */


SDS011 	  my_sds;
RF24      radio(9,10);

uint8_t   radioBuffer[32]    = {0};

uint16_t  cntDATA = SLEEP_DATA;
uint16_t  cntVOLT = SLEEP_VOLT;

float     p10            = 0;
float     p25            = 0;
float     pressure       = 0;
float     voltage        = 0;
int       error          = 0;


void radioSetup(){
  radio.begin();
  radio.setChannel(RF24_CH);
  radio.setDataRate(RF24_250KBPS);
  radio.setPALevel(RF24_PA_MAX);
  radio.setCRCLength(RF24_CRC_16);
  radio.setRetries(10, 15);  
  radio.setAutoAck(1);
  radio.openReadingPipe(1, node_address);
  radio.openWritingPipe(server_address);

  DEBUG_RADIO();
}

void setup() {
  delay(500);

  #if LOGDEBUG==1
  Serial.begin(115200);
  printf_begin();
  #endif

  pinMode(SDS_ON, OUTPUT);
  digitalWrite(SDS_ON, HIGH);

  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);   

  //flash led
  digitalWrite(LED_PIN, HIGH);
  delay(250);
  digitalWrite(LED_PIN, LOW);
  
  //1.1V internal voltage reference
  analogReference(INTERNAL);

  radioSetup();

  digitalWrite(SDS_ON, LOW);
  delay(250);
  my_sds.begin(6, 7); //RX, TX
  delay(250);
  my_sds.sleep();
  
  //flash led
  delay(500);
  digitalWrite(LED_PIN, HIGH);
  delay(1000);
  digitalWrite(LED_PIN, LOW);
}

void loop() {
  DEBUG_PRINTLN(">");

  if( (cntDATA >= SLEEP_DATA) || (cntVOLT >= SLEEP_VOLT)){

    if(cntDATA >= SLEEP_DATA){
      //Power on SDS011 and wait a little
      my_sds.wakeup();

      //wait for air flow
      delay(5000);

      uint8_t  counter = 0;
      float    sumP25  = 0;
      float    sumP10  = 0;
     

      for(uint8_t i = 0; i < 5; i++){
         error = my_sds.read(&p25, &p10);
         if (!error) {
            sumP25 += p25;
            sumP10 += p10;
            DEBUG_PRINTLN(counter);
            ++counter;
         }
         else{
            DEBUG_PRINTLN("Error");
         }
         delay(1000);
      }

      my_sds.sleep();

      if(counter >= 3){
         sumP25 /= counter;
         sumP10 /= counter;

         DEBUG_PRINT("P25=");
         DEBUG_PRINT(sumP25);
         DEBUG_PRINT(", P10=");
         DEBUG_PRINTLN(sumP10);
	  
	  
	     memcpy(radioBuffer,     &nodeId,             2);
         memcpy(radioBuffer+2,   "DATA",              4);
    
         memcpy(radioBuffer+6,   &sumP25,             4);
         memcpy(radioBuffer+10,  &sumP10,             4);

         memset(radioBuffer+14,  0,                  18);    

		 if(radio.write(radioBuffer, 32)){
		   cntDATA = 0;
		 }
		 else{
		   if(cntDATA >= (SLEEP_DATA+5)){
		     //retry up to 5 cycles of 8s.
			 cntDATA = 0;
		   }
		 }
	  }
    }

    delay(250);
    radio.flush_tx();

    if(cntVOLT >= SLEEP_VOLT){
      voltage = analogRead(VT_PIN);
      voltage = voltage * 1.1 * ((2470000.0)/470000.0) / 1024.0;
    
      DEBUG_PRINT("V=");
      DEBUG_PRINTLN(voltage);

     
      memcpy(radioBuffer,     &nodeId,           2);
      memcpy(radioBuffer+2,   "VOLT",            4);
    
      memcpy(radioBuffer+6,   &voltage,          4);

      memset(radioBuffer+10,  0,                 22);
    

      if(radio.write(radioBuffer, 32)){
        cntVOLT = 0;
      }
      else{
        if(cntVOLT >= (SLEEP_VOLT+5)){
          //retry up to 5 cycles of 8s.
          cntVOLT = 0;
        }
      }
    }   

    delay(50);

  }
  
   
  ++cntDATA;
  ++cntVOLT;
  
  //flash led
  digitalWrite(LED_PIN, HIGH);
  delay(1);
  digitalWrite(LED_PIN, LOW);

  DEBUG_PRINTLN("."); 

  LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);

}